Metaliq Components and MTASC

			import com.metaliq.controls.Button;
			import com.metaliq.skins.FocusRect;
			import com.metaliq.skins.gskin1.ButtonBackground;

			class ButtonTest {
				// content holder
				var content:MovieClip;

				function ButtonTest() {
					// create dummy variables to pull in required classes for mtasc
					var fr:FocusRect;
					delete fr;
					var bb:ButtonBackground;
					delete bb;

					content = ButtonTest.parent.createEmptyMovieClip("content", 0);

					var sample_btn:Button = content.createClassObject(Button, "sample_btn", content.getNextHighestDepth(), {
						icon:"icon1",
						label:"Hello world!",
						labelPlacement:"right",
						selected:false,
						toggle:true,
						enabled:true,
						visible:true,
						minWidth:15,
						minHeight:15,
						_x:10,
						_y:10,
						_width:150
					});

					configButton();
				}

				private function configButton():Void {
					content.sample_btn.addEventListener("click", onButtonClick);
				}

				private function onButtonClick(evtObj:Object):Void {
					if (evtObj.target._name == "sample_btn") {
						trace("you clicked the button");
					}
				}


				// APPLICATION INITIALIZATION

				static var application:ButtonTest;
				static var parent:MovieClip

				/**
				* Application entry point
				*/
				static function main(scope:MovieClip) {
					parent = scope;

					// create the content
					application = new ButtonTest();
				}
			}
			

If you look at the class above, you will notice a main method that gets called by mtasc. This main method creates an instance of the ButtonTest class which in turn begins the setup for instantiating a Metaliq component through code. We are using the createClassObject method to instantiate the Button component. The parameters passed are className, instanceName, depth, and an initObject which sets the defaults for the component. Besides the Button class, two other classes are imported in for mtasc. Once you get through with the following steps, remove those imports and the instantiations of those classes to see the error that mtasc throws. It will clearly ask you to force compilation of those classes. The easiest way to do that is by adding in the import statement for each class and then creating a reference to the class by instantiating it. I immediately delete the instance so it doesn’t take up memory.

			public function set background(p_bg:String):Void { super.background = p_bg; };
			

For some reason, even though BaseButton extends UIObject, without the above statement the call to set background does not automatically go up the chain to UIObject without explicitly forcing it to. If you compile now, you should see the background behind the button. You now have a fully working example of a Metaliq component being compiled with mtasc.